Emacs: Convert to Full-Width Characters 🚀

This command convert all English letters and digits and punctuations, from/to half-width and full-width.

[see Unicode: Full-Width Characters]

(defun xah-convert-fullwidth-chars (Begin End &optional ToASCII)
  "Convert English alphabets and punctuation to Chinese fullwidth chars. (or from)
Works on current line or text selection.

Example of fullwidth chars: ａｂｃ

If `universal-argument' is called first, ask for conversion direction. else, if the command has been repeated, do toggle, else, to fullwidth.

When called in lisp code, Begin End are region begin/end positions. ToASCII, if true, change to ASCII (non-fullwidth chars).

URL `http://xahlee.info/emacs/emacs/elisp_convert_full_width_half_width_chars.html'
Version: 2018-08-02 2023-05-12_113123"
  (interactive
   (let (xp1 xp2)
     (if (use-region-p)
         (setq xp1 (region-beginning) xp2 (region-end))
       (setq xp1 (line-beginning-position) xp2 (line-end-position)))
     (list xp1 xp2
           (if current-prefix-arg
               (if (string-equal (completing-read "Direction:" '("fullwidth" "ascii")) "ascii")
                   t
                 nil
                 )
             (if (equal last-command this-command)
                 (let ((xstate (get 'xah-convert-fullwidth-chars 'toASCII)))
                   (cond
                    ((eq xstate 1) nil)
                    ((eq xstate 0) t)
                    (t nil)))
               nil
               )))))
  (let ((xcharMap
         [
          ["0" "０"] ["1" "１"] ["2" "２"] ["3" "３"] ["4" "４"] ["5" "５"] ["6" "６"] ["7" "７"] ["8" "８"] ["9" "９"]
          ["A" "Ａ"] ["B" "Ｂ"] ["C" "Ｃ"] ["D" "Ｄ"] ["E" "Ｅ"] ["F" "Ｆ"] ["G" "Ｇ"] ["H" "Ｈ"] ["I" "Ｉ"] ["J" "Ｊ"] ["K" "Ｋ"] ["L" "Ｌ"] ["M" "Ｍ"] ["N" "Ｎ"] ["O" "Ｏ"] ["P" "Ｐ"] ["Q" "Ｑ"] ["R" "Ｒ"] ["S" "Ｓ"] ["T" "Ｔ"] ["U" "Ｕ"] ["V" "Ｖ"] ["W" "Ｗ"] ["X" "Ｘ"] ["Y" "Ｙ"] ["Z" "Ｚ"]
          ["a" "ａ"] ["b" "ｂ"] ["c" "ｃ"] ["d" "ｄ"] ["e" "ｅ"] ["f" "ｆ"] ["g" "ｇ"] ["h" "ｈ"] ["i" "ｉ"] ["j" "ｊ"] ["k" "ｋ"] ["l" "ｌ"] ["m" "ｍ"] ["n" "ｎ"] ["o" "ｏ"] ["p" "ｐ"] ["q" "ｑ"] ["r" "ｒ"] ["s" "ｓ"] ["t" "ｔ"] ["u" "ｕ"] ["v" "ｖ"] ["w" "ｗ"] ["x" "ｘ"] ["y" "ｙ"] ["z" "ｚ"]
          ["," "，"] ["." "．"] [":" "："] [";" "；"] ["!" "！"] ["?" "？"] ["\"" "＂"] ["'" "＇"] ["`" "｀"] ["^" "＾"] ["~" "～"] ["¯" "￣"] ["_" "＿"]
          [" " "　"]
          ["&" "＆"] ["@" "＠"] ["#" "＃"] ["%" "％"] ["+" "＋"] ["-" "－"] ["*" "＊"] ["=" "＝"] ["<" "＜"] [">" "＞"] ["(" "（"] [")" "）"] ["[" "［"] ["]" "］"] ["{" "｛"] ["}" "｝"] ["(" "｟"] [")" "｠"] ["|" "｜"] ["¦" "￤"] ["/" "／"] ["\\" "＼"] ["¬" "￢"] ["$" "＄"] ["£" "￡"] ["¢" "￠"] ["₩" "￦"] ["¥" "￥"]
          ]
         ))

    (save-restriction
      (narrow-to-region Begin End)
      (let ((case-fold-search nil))
        (mapc
         (lambda (xx)
           (goto-char (point-min))
           (while (search-forward (elt xx 0) nil t)
             (replace-match (elt xx 1) t t)))
         (if ToASCII
             (mapcar (lambda (x) (vector (elt x 1) (elt x 0))) xcharMap)
           xcharMap
           ))))

    (put 'xah-convert-fullwidth-chars 'toASCII (if ToASCII 1 0))
    ;; if toASCII is 1, it means the last time the command was called, it changed text to ascii
    ))